Team:Johns Hopkins/Modeling/VitCPathLBS

The L-Ascorbate Pathway Model in LBS

directive sample 900.0 5000
 
// Compartments
comp cytosol = new comp;
 
// Enzymes
spec sub_GDP_D_mannose_epimerase = new{};
spec GDP_D_mannose_epimerase = new{};
spec GDP_L_Gal_phosphorylase = new{};
spec Gal_P_phosphatase = new{};
spec D_Ara_dehydrogenase = new{};
spec D_Ara_Lac_oxidase= new{};
spec GDP = new{};
 
// Metabolites
spec GDP_D_Man = new{};
spec GDP_L_Gal = new{};
spec L_Gal_P = new{};
spec L_Gal = new{};
spec L_Gal_Lac = new{};
spec L_ascorbate = new{};
 
// Rate constants
rate GDP_clearance = 1.0*10^-9;
rate kb = 0.01;
rate ku = 1.0*10^-4;
rate GDP_D_mannose_epimerase_Km = 0.0045;
rate GDP_D_mannose_epimerase_Kcat = 0.041;
rate Ki = 5.0e-4;
rate GDP_L_Gal_phosphorylase_Km = 0.01;
rate GDP_L_Gal_phosphorylase_Kcat = 13.0;
rate Gal_P_phosphatase_Km = 0.107;
rate Gal_P_phosphatase_Kcat = 6.0;
rate D_Ara_dehydrogenase_Km = 180.0;
rate D_Ara_dehydrogenase_Kcat = 125.0;
rate L_Gal_Lac_dehydrogenase_Km = 53.7;
rate L_Gal_Lac_dehydrogenase_Kcat = 18.8;
 
module mmInhibitionRXN(spec sub, enz, prod, inhib; rate km, kcat, k) {
	rate rxn_rate = kcat*enz/(sub+km*(1+inhib/k));
	sub + enz ->[rxn_rate] enz + prod
};
 
module mmRXN(spec sub, enz, prod; rate km, kcat) {
	rate rxn_rate = kcat*enz/(sub+km);
	sub + enz ->[rxn_rate] enz + prod
};
 
module mmTwoProductsRXN(spec sub, enz, prod1, prod2; rate km, kcat) {
	rate rxn_rate = kcat*enz/(sub+km);
	sub + enz ->[rxn_rate] enz + prod1 + prod2
};
 
cytosol[
	sub_GDP_D_mannose_epimerase + sub_GDP_D_mannose_epimerase <->{kb}{ku} 
GDP_D_mannose_epimerase |
	mmInhibitionRXN(GDP_D_Man, GDP_D_mannose_epimerase, GDP_L_Gal, GDP, 
GDP_D_mannose_epimerase_Km, GDP_D_mannose_epimerase_Kcat, Ki) |
	mmTwoProductsRXN(GDP_L_Gal, GDP_L_Gal_phosphorylase, L_Gal_P, GDP, 
GDP_L_Gal_phosphorylase_Km, GDP_L_Gal_phosphorylase_Kcat) |
	mmRXN(L_Gal_P, Gal_P_phosphatase, L_Gal, Gal_P_phosphatase_Km, Gal_P_phosphatase_Kcat) |
	mmRXN(L_Gal, D_Ara_dehydrogenase, L_Gal_Lac, D_Ara_dehydrogenase_Km, 
D_Ara_dehydrogenase_Kcat) |
	mmRXN(L_Gal_Lac, D_Ara_Lac_oxidase, L_ascorbate, L_Gal_Lac_dehydrogenase_Km, 
L_Gal_Lac_dehydrogenase_Kcat) |
		->{10} GDP_D_Man |
		GDP ->{GDP_clearance} |
		init sub_GDP_D_mannose_epimerase 1 |
		init GDP_D_mannose_epimerase 0 |
		init GDP_L_Gal_phosphorylase 1 |
		init Gal_P_phosphatase 1 | 
		init D_Ara_dehydrogenase 1 |
		init D_Ara_Lac_oxidase 1 |
		init GDP 0
]