"
The Full Pathway+Expression Beta-Carotene Model in LBS
directive sample 90000.0 5000
// Compartments
comp cytosol = new comp;
comp nucleus = new comp inside cytosol;
// Transcriptional machinery
spec Ribo = new{mrna:binding};
spec RNAP = new{dna:binding,mrna:binding};
//Gene-Ezyme Pairs
spec crtE = new{bind:binding}; spec GGPP_synth_exo = new{};
spec BTS1 = new{bind:binding}; spec GGPP_synth_endo = new{};
spec crtYB = new{bind:binding}; spec carotene_desat = new{};
spec crtI = new{bind:binding}; spec phytoene_synth_lycopene_cyc = new{};
// Metabolites
spec farnesyl_PP = new{};
spec GGPP = new{};
spec phytoene = new{};
spec neurosporene = new{};
spec lycopene = new{};
spec beta_carotene = new{};
spec hh_beta_carotene = new{};
// Rate constants
rate GGPP_synth_endo_Km = 0.0032;
rate GGPP_synth_endo_Kcat = 0.025;
rate GGPP_synth_exo_Km = 0.0032;
rate GGPP_synth_exo_Kcat = 0.025;
rate phytoene_synth_Km = 0.0030;
rate phytoene_synth_Kcat = 0.0526;
rate carotene_desat_neurosporene_Km = 0.0084;
rate carotene_desat_neurosporene_Kcat = 11.9665;
rate carotene_desat_lycopene_Km = 0.0090;
rate carotene_desat_lycopene_Kcat = 0.9703;
rate phytoene_synth_hh_beta_carotene_Km = 0.0090;
rate phytoene_synth_hh_beta_carotene_Kcat = 0.3881;
rate phytoene_synth_beta_carotene_Km = 0.0018;
rate phytoene_synth_beta_carotene_Kcat = 0.00038623;
//Transcription Kinetics
rate rna_deg = 0.0058;
rate rna_falloff = 0.01;
rate rnap_bind = 0.5;
rate transcription = 10;
rate termination = 10;
rate ribo_bind = 0.1;
rate ribo_unbind = 0.01;
rate translation = 10;
rate export = 0.01;
rate prot_deg = 0.01;
module transcribe(spec DNA:{bind}, mRNA:{down}) {
RNAP{dna} + DNA{bind} ->{rnap_bind} RNAP{dna!1}-DNA{bind!1} |
RNAP{dna!1}-DNA{bind!1} ->{transcription} mRNA{down!2}-
RNAP{dna!1,mrna!2}-DNA{bind!1} |
mRNA{down!2}-RNAP{dna!1,mrna!2}-DNA{bind!1} ->{termination} mRNA{down}
+ RNAP{dna,mrna} + DNA{bind}
};
module translate(spec mRNA:{up}, Prot) {
Ribo{mrna} + mRNA{up} <->{ribo_bind}{ribo_unbind}
Ribo{mrna!1}-mRNA{up!1} |
Ribo{mrna!1}-mRNA{up!1} ->{translation} Ribo{mrna} + mRNA{up} + Prot
};
module express(comp nuc; spec DNA:{bind}, Prot) {
spec mRNA = new{up:binding,down:binding};
nuc[ transcribe(DNA:{bind}, mRNA:{down}) | mRNA ->{rna_deg} ] |
nuc[ mRNA ] ->{export} mRNA |
translate(mRNA:{up}, Prot) | mRNA -> {rna_deg}
};
module mmRXN(spec sub, enz, prod; rate km, kcat) {
rate rxn_rate = kcat*enz/(sub+km);
sub + enz ->[rxn_rate] enz + prod
};
cytosol[
express(nucleus, crtE:{bind}, GGPP_synth_exo) |
express(nucleus, BTS1:{bind}, GGPP_synth_endo) |
express(nucleus, crtYB:{bind}, phytoene_synth_lycopene_cyc) |
express(nucleus, crtI:{bind}, carotene_desat) |
mmRXN(farnesyl_PP, GGPP_synth_endo, GGPP, GGPP_synth_endo_Km,
GGPP_synth_endo_Kcat) |
mmRXN(farnesyl_PP, GGPP_synth_exo, GGPP, GGPP_synth_exo_Km,
GGPP_synth_exo_Kcat) |
mmRXN(GGPP, phytoene_synth_lycopene_cyc, phytoene, phytoene_synth_Km,
phytoene_synth_Kcat) |
mmRXN(phytoene, carotene_desat, neurosporene,
carotene_desat_neurosporene_Km, carotene_desat_neurosporene_Kcat) |
mmRXN(neurosporene, carotene_desat, lycopene,
carotene_desat_lycopene_Km, carotene_desat_lycopene_Kcat) |
mmRXN(neurosporene, carotene_desat, hh_beta_carotene,
phytoene_synth_hh_beta_carotene_Km, phytoene_synth_hh_beta_carotene_Kcat) |
mmRXN(lycopene, phytoene_synth_lycopene_cyc, beta_carotene,
phytoene_synth_beta_carotene_Km, phytoene_synth_beta_carotene_Kcat) |
GGPP_synth_exo ->{prot_deg} |
GGPP_synth_endo ->{prot_deg} |
carotene_desat ->{prot_deg} |
phytoene_synth_lycopene_cyc ->{prot_deg} |
->{100} farnesyl_PP |
init Ribo 10 |
nucleus[
init crtE 5 |
init crtYB 5 |
init crtI 5 |
init RNAP 1
]
]
